1000 rem LOW RES PLOT DEMO #4
1010 rem D.M.BROAD. 19/2/89.
1020 :
1030 MR=512: dim RX%(MR),RY%(MR)
1040 TX=0: TY=0: BX=80: BY=50
1050 I$=chr$(19)+"    "+chr$(19)
1060 RD=dec("7F2")    :rem READ ADDR
1070 PL=dec("1010")   :rem SYS ADDR
1080 sys PL,11, 0,0   :rem SCREEN
1090 sys PL,0         :rem INITGR
1100 sys PL,3,  6,0,0 :rem SELWIN
1110 sys PL,5         :rem CLEARW
1120 :
1130 rem DRAW TRIANGLE
1140 W=40:M=W/2:CX=(BX-W)/2:CY=(BY-M)/2
1150 sys PL,7,CX,CY   :rem MOVETO
1160 sys PL,1,CX+W,CY :rem LINETO
1170 sys PL,1,CX+M,CY+M:rem LINETO
1180 sys PL,1,CX,CY   :rem LINETO
1190 :
1200 print chr$(19)"     BASIC CODED PAINT"
1210 print " ^" chr$(13) " STACK"
1220 RX%(0)=CX+W/2:RY%(0)=CY+6:IR=0
1230 gosub 1270
1240 end
1250 :
1260 rem BASIC PAINT!
1270 print I$ IR;
1280 A=RX%(IR): B=RY%(IR)
1290 sys PL,4,A,B    :rem PLOT
1300 IR=IR-1
1310 if A+1=BX then 1350
1320 :sys PL,18,A+1,B:rem READ
1330 :if peek(RD)<>0 then 1350
1340 : IR=IR+1:RX%(IR)=A+1:RY%(IR)=B
1350 if A-1<TX then 1390
1360 :sys PL,18,A-1,B:rem READ
1370 :if peek(RD)<>0 then 1390
1380 : IR=IR+1:RX%(IR)=A-1:RY%(IR)=B
1390 if B+1=BY then 1430
1400 :sys PL,18,A,B+1:rem READ
1410 :if peek(RD)<>0 then 1430
1420 : IR=IR+1:RX%(IR)=A:RY%(IR)=B+1
1430 if B-1<TY then 1480
1440 :sys PL,18,A,B-1:rem READ
1450 :if peek(RD)<>0 then 1480
1460 : IR=IR+1:RX%(IR)=A:RY%(IR)=B-1
1470 :
1480 if (IR>=0) and (IR<>MR) then 1270
1490 return
1500 :