1000 rem LOW RES PLOT DEMO #3
1010 rem D.M.BROAD. 19/2/89.
1020 :
1030 trap 1420
1040 PL=dec("1010")   :rem SYS ADDR
1050 sys PL,11,  0,0  :rem SCREEN
1060 def fn F(F)= sin(F/D)*E+E
1070 :
1080 print chr$(147)chr$(5)
1090 W=0: input "NO.CYCLES";W
1100 W=W*2:if W<=0 then end
1110 :
1120 sys PL, 0        :rem INITGR
1130 sys PL, 3,  2,0,0:rem SELWIN
1140 sys PL, 5        :rem CLEARW
1150 sys PL, 7,  1,0  :rem MOVETO
1160 sys PL,15, 78,49 :rem BOX
1170 :
1180 rem DEFINE WINDOW
1190 MX=72       : MY=42:rem SIZE
1200 PX=(80-MX)/2: PY=(50-MY)/2
1210 QX=MX+PX    : QY=MY+PY
1220 sys PL, 7,PX,PY  :rem MOVETO
1230 sys PL, 2,QX,QY,1:rem SETWIN
1240 sys PL, 3,94,0 ,1:rem SELWIN
1250 :
1260 rem DRAW AXIS
1270 E=MY/2
1280 sys PL, 7, 0,0   :rem MOVETO
1290 sys PL, 1, 0,MY  :rem LINETO
1300 sys PL, 7, 0,E   :rem MOVETO
1310 sys PL, 1,MX,E   :rem LINETO
1320 char 1,30,24,"SINE WAVE"
1330 :
1340 rem DRAW SINE WAVE
1350 D=MX/(W*pi): S=1/W
1360 sys PL, 7, 0,E   :rem MOVETO
1370 :
1380 for X=0 to MX step S
1390 :sys PL, 4, X,MY-fn F(X):rem PLOT
1400 next
1410 :
1420 char 1,1,24,"PRESS SPACE"
1430 do:  get S$
1440 loop until S$=" "
1450 run